/\*SAS PROC MIXED code for the repeated-measures analysis of data in the following Excel file: VCO2 and EWL data for PROC MIXED.xlsx\*/

/\*Code to ensure data are sorted correctly\*/

PROC SORT DATA = SFDVCO2EWL;

 BY sfdstatus sex snakeid temp;

PROC PRINT DATA = SFDVCO2EWL noobs;

RUN;

/\*Code for rmANCOVA for VCO2 data\*/

TITLE 'rmANCOVA for the effects of SFD status & temperature on log VCO2';

PROC MIXED DATA = SFDVCO2EWL method = reml update;

 CLASS sfdstatus temp snakeid;

 MODEL logvco2 = sfdstatus|temp logmass / outpm=residuals ddfm=kr2;

 REPEATED temp / SUB=snakeid TYPE=cs;

 LSMEANS sfdstatus sfdstatus\*temp;

 LSMEANS temp / adjdfe=row adjust=TUKEY;

RUN;

/\*Code to test for normality of residuals\*/

PROC PRINT DATA = residuals noobs;

RUN;

PROC UNIVARIATE DATA=residuals NORMAL PLOT;

 VAR resid;

RUN;

/\*Code for slope homogeneity test\*/

PROC MIXED DATA = SFDVCO2EWL method = reml update;

 CLASS sfdstatus temp snakeid;

 MODEL logvco2 = sfdstatus|temp|logmass / ddfm=kr2;

 REPEATED temp / SUB=snakeid TYPE=cs;

RUN;

/\*Code for repeated-measures multiple regression for VCO2 data\*/

/\*Generates allometric equations to predict logvco2 as a function of log body mass and temperature, separately by SFD status.\*/

TITLE 'Repeated-measures multiple regression using PROC MIXED';

PROC MIXED DATA = SFDVCO2EWL method = reml update;

 CLASS sfdstatus snakeid;

 BY sfdstatus;

 MODEL logvco2 = logmass temp / solution ddfm=kr2;

 REPEATED / SUB=snakeid TYPE=cs;

RUN;

/\*Code for rmANCOVA for EWL data\*/

TITLE 'rmANCOVA for the effects of SFD status & temperature on log EWL';

PROC MIXED DATA = SFDVCO2EWL method = reml update;

 CLASS sfdstatus temp snakeid;

 MODEL logewl = sfdstatus|temp logsvl / outpm=residuals2 ddfm=kr2;

 REPEATED temp / SUB=snakeid TYPE=toep;

 LSMEANS sfdstatus sfdstatus\*temp;

 LSMEANS temp / adjdfe=row adjust=TUKEY;

RUN;

/\*Code to test for normality of residuals\*/

PROC PRINT DATA = residuals2 noobs;

RUN;

PROC UNIVARIATE DATA=residuals2 NORMAL PLOT;

 VAR resid;

RUN;

/\*Code for slope homogeneity test\*/

PROC MIXED DATA = SFDVCO2EWL method = reml update;

 CLASS sfdstatus temp snakeid;

 MODEL logewl = sfdstatus|temp|logsvl / ddfm=kr2;

 REPEATED temp / SUB=snakeid TYPE=toep;

RUN;